Na}{

File Content: `warn.cocci`

// SPDX-License-Identifier: GPL-2.0-only
/// Use WARN(1,...) rather than printk followed by WARN_ON(1)
///
// Confidence: High
// Copyright: (C) 2012 Julia Lawall, INRIA/LIP6.
// Copyright: (C) 2012 Gilles Muller, INRIA/LiP6.
// URL: http://coccinelle.lip6.fr/
// Comments:
// Options: --no-includes --include-headers

virtual patch
virtual context
virtual org
virtual report

@bad1@
position p;
@@

printk(...);
printk@p(...);
WARN_ON(1);

@r1 depends on context || report || org@
position p != bad1.p;
@@

 printk@p(...);
*WARN_ON(1);

@script:python depends on org@
p << r1.p;
@@

cocci.print_main("printk + WARN_ON can be just WARN",p)

@script:python depends on report@
p << r1.p;
@@

msg = "SUGGESTION: printk + WARN_ON can be just WARN"
coccilib.report.print_report(p[0],msg)

@ok1 depends on patch@
expression list es;
position p != bad1.p;
@@

-printk@p(
+WARN(1,
  es);
-WARN_ON(1);

@depends on patch@
expression list ok1.es;
@@

if (...)
- {
  WARN(1,es);
- }

// --------------------------------------------------------------------

@bad2@
position p;
@@

printk(...);
printk@p(...);
WARN_ON_ONCE(1);

@r2 depends on context || report || org@
position p != bad1.p;
@@

 printk@p(...);
*WARN_ON_ONCE(1);

@script:python depends on org@
p << r2.p;
@@

cocci.print_main("printk + WARN_ON_ONCE can be just WARN_ONCE",p)

@script:python depends on report@
p << r2.p;
@@

msg = "SUGGESTION: printk + WARN_ON_ONCE can be just WARN_ONCE"
coccilib.report.print_report(p[0],msg)

@ok2 depends on patch@
expression list es;
position p != bad2.p;
@@

-printk@p(
+WARN_ONCE(1,
  es);
-WARN_ON_ONCE(1);

@depends on patch@
expression list ok2.es;
@@

if (...)
- {
  WARN_ONCE(1,es);
- }

Name	Size	Permission
add_namespace.cocci	837 bytes	0644
array_size.cocci	1729 bytes	0644
badty.cocci	1729 bytes	0644
boolconv.cocci	1506 bytes	0644
boolinit.cocci	2449 bytes	0644
boolreturn.cocci	698 bytes	0644
bugon.cocci	1515 bytes	0644
cond_no_effect.cocci	2121 bytes	0644
cstptr.cocci	852 bytes	0644
doubleinit.cocci	1408 bytes	0644
ifaddr.cocci	684 bytes	0644
ifcol.cocci	1258 bytes	0644
irqf_oneshot.cocci	1951 bytes	0644
noderef.cocci	1219 bytes	0644
of_table.cocci	1366 bytes	0644
orplus.cocci	1053 bytes	0644
returnvar.cocci	1286 bytes	0644
semicolon.cocci	1095 bytes	0644
warn.cocci	1686 bytes	0644

File Content: warn.cocci

File Content: `warn.cocci`